module prism(l, w, h) {
  polyhedron(
    points=[
      [0,0,h],           // 0    front top corner
      [0,0,0], [w,0,0],  // 1, 2 front left & right bottom corners
      [0,l,h],           // 3    back top corner
      [0,l,0], [w,l,0]   // 4, 5 back left & right bottom corners
    ],
    faces=[       // points for all faces must be ordered clockwise when looking in
      [0,2,1],    // top face
      [3,4,5],    // base face
      [0,1,4,3],  // h face
      [1,2,5,4],  // w face
      [0,3,5,2],  // hypotenuse face
    ]
  );
}

baseThickness = 3;
baseHeight = 40;
baseWidth = 80;

gapWidth = 30;
clampDepth = 15;
clampHeight = 5;

threadDiameter = 7;
threadTubeOuterDiameter = threadDiameter+baseThickness*2;

difference() {
  union() {
    cube([baseThickness, baseWidth, baseHeight]);
    
    translate([-clampDepth, 0, 0])
      cube([clampDepth, baseWidth, baseThickness]);
    
    translate([-clampDepth, 0, baseThickness])
      prism(baseWidth, clampDepth, clampHeight);
    
    translate([0, (baseWidth - threadTubeOuterDiameter)/2, 0])
      cube([threadTubeOuterDiameter/2, threadTubeOuterDiameter, baseHeight]);
    
    translate([threadTubeOuterDiameter/2, baseWidth/2, 0])
      cylinder(r = threadTubeOuterDiameter/2, h = baseHeight);
  }
  
  // thread hole
  translate([threadTubeOuterDiameter/2, baseWidth/2, 0])
    cylinder(r = threadDiameter/2, h = baseHeight);
  
  // clamp gap
  translate([-clampDepth, (baseWidth-gapWidth)/2, 0])
    cube([clampDepth, gapWidth, clampHeight+baseThickness]);
}